Div GO : Div Games Online

Haz clic para obtener el control del teclado

// Ejemplo de Div GO (Games Online)
// by J. Manuel Habas

program ejemplo_set_vpad;
begin
	set_title("Div GO : Ejemplo de set_vpad");
    set_color(cc_black);
    
	set_mode(400, 200, 2);
    set_fps(60, 0);
    
    screen_scanline(20,2);
    screen_smooth(false);
	screen_color(#025);
    
	// inicia scroll
	start_scroll(0, 0, 2, 2, 0, 0);
    set_half_scroll(0, 2);

scroll.front.alpha	= 100;
    scroll.front.tone	= 10;
    
    scroll.half.alpha	= 80;
    scroll.half.tone	= 20;
    scroll.half.blur	= 2;
    
	scroll.back.alpha	= 60;
    scroll.back.tone	= 30;
    scroll.back.blur	= 4;
    
    scroll.camera = id;
	
	text_color = #fff;
	text_size  = 50;
	
    write(0, 200, 10, 4, "Pulsa [1, 6] para mostrar u ocultar el vpad");
    write(0, 200, 25, 4, "Pulsa SPACE para disparar");
	
	nave(200, 180);
    
    ctype = c_scroll;
	
	loop
    	y--;
        
        if (key(_1)) set_vpad(false, 0); end
        if (key(_2)) set_vpad(true, 20); end
        if (key(_3)) set_vpad(true, 40); end
        if (key(_4)) set_vpad(true, 60); end
        if (key(_5)) set_vpad(true, 80); end
        if (key(_6)) set_vpad(true, 100); end
        
		if (key(_esc)) exit("Amaka Soft 2021", 1); end

frame;
	end
end

process nave(x, y);
private
	disparado;
	
begin
	graph = 6;
	size  = 30;
	
	loop		
		if ((key(_left) or pad.left) and x > 20)
            x -= 3;
		end
		
		if ((key(_right) or pad.right) and x < 380)
            x += 3;
		end
		
		if ((key(_space) or pad.button0) and disparado < 1)
			disparo(x, y-10);
			disparado = 5;
		end
		
        if (key(_a)) signal(type disparo, s_kill); end
        if (key(_z)) signal(type disparo, s_freeze); end
		disparado --; if (disparado < 0) disparado = 0; end
		
		frame;
	end
end

process disparo(x, y);
begin
	graph = 3;
	angle = 90000;
	size  = 10;
	z	  = 10;
    tone  = 30;
	
	loop
		y -= 5; if (y < -10) break; end
		
        explosion(x, y+10 );
		frame;
	end
end

process explosion(x, y);
begin
	graph = 1;
    size  = 5;
    z 	  = 20;
    alpha = 80;
    saturate = 300;
    
    loop
        angle = rand(0, 360000);
        size ++;
        alpha -= 10; if (alpha < 10) break; end
        
        frame;
    end
end

Tamaño Código:

HTML5 Game engine

Entorno de desarrollo de juegos online en HTML5