Div GO : Div Games Online

Haz clic para obtener el control del teclado

// Pruebas de compilador online Div GO
// Php + Html5 + Canvas + Javascript
// by J. Manuel Habas

program ejemplo_efectos_en_regiones;
global
	existe;
    
begin
	set_title("Div GO : Ejemplo efectos en regiones");
	
	/* opciones de pantalla */
	set_mode(480, 240); //pone tamaño al canvas
	screen_color(#26b); //pone color

set_fps(60, 0);		//pone los frames por segundo

// define las regiones donde mostrar los graficos
	define_region(1, 0,	  0,   240, 120);
	define_region(2, 0,	  120, 240, 120);
    define_region(3, 240, 0,   240, 120);
    define_region(4, 240, 120, 240, 120);

// inicia scroll
	start_scroll(0, 0, 1, 2, 1, 0);
	start_scroll(1, 0, 1, 2, 2, 0);
	
	flecha(3, 120, 60, 0, 2, 1);
	
	text_size = 50; // cambia la medida global de los textos
	text_color = #26b; // cambia el color global de los textos
	write(0, 241, 11, 4, "Pulsa [0][1][2][3] para cambiar efectos a las regiones");
	write(0, 241, 31, 4, "Pulsa [ESC] para eliminar región 4 y [ENTER] para volverla a definirla");
    
    write_int(0, 241, 121, 0, &existe);
    
	text_color = cc_white; // cambia el color global de los textos
	write(0, 240, 10, 4, "Pulsa [0][1][2][3] para cambiar efectos a las regiones");
	write(0, 240, 30, 4, "Pulsa [ESC] para eliminar región 4 y [ENTER] para volverla a definirla");

write_int(0, 240, 120, 0, &existe);

// añade efectos a las regiones
	region_color(1, cc_orange); //región 1
	region_pixelated(2, 90); 	//región 2
    region_copy(3, 2);			//región 3
    region_copy(4, 1);			//región 4
    
    loop
    	existe = is_defined_region(4);
    
    	if (key(_0))
    		region_color(1, cc_orange);
    		region_pixelated(2, 90);
        end
    	if (key(_1)) 
            region_wave(1, 0, 5, 10); 
            region_wave(2, 1, 10, 10); 
        end
        if (key(_2)) 
        	region_mask(1, 0, 7, 120, 60, 100, 100); 
            region_color(2, rgb_to_grb); 
        end
        if (key(_3)) 
        	region_blur(1, 20); 
            region_zoom(2, 120, 60, 100);
        end
        
        if (key(_esc)) delete_region(4); end
        if (key(_enter)) define_region(4, 240, 120, 240, 120); region_copy(4, 1); end //define y vuelve a copiar en la región 4 lo que muestra la región 1
        
    	frame;
    end
end

process flecha(graph, x, y, angle, region, cam);
begin
	size	= 100;
	ctype	= c_scroll;
	
    scroll[cam].camera = id;

loop
		if (key(_up))	 y -= 2; angle = 90000;	 end
		if (key(_down))  y += 2; angle = -90000; end
		if (key(_left))  x -= 2; angle = 180000; end
		if (key(_right)) x += 2; angle = 0; 	 end
	
		frame;
	end
end

Tamaño Código:

HTML5 Game engine

Entorno de desarrollo de juegos online en HTML5