Div GO : Div Games Online

Haz clic para obtener el control del teclado

/*
	Ejemplo Div GO para hokuto40
    by J. Manuel Habas
*/

program ejemplo_de_niveles;
global
    puntos	 	 = 0;
    enemigos	 = 0;
    vidas		 = 5;
    jugador_vive = 0;
	
begin
	set_title("Ejemplo de niveles");
    set_icon("graficos/009.png");

set_mode(480, 300);
	set_fps(60, 0);

pasar_nivel(nivel1);
	
	loop		
		if (key(_esc)) exit("Amaka Soft 2019", 1); end

frame;
	end
end

process pasar_nivel(nivel);
begin
	fade_off();
    
	let_me_alone();
    stop_scroll(0);
    delete_text(all_text);

nivel();
    
    fade_on();
end

process reiniciar_nivel(nivel);
begin
	fade_off();
    
	let_me_alone();
    stop_scroll(0);
    delete_text(all_text);

vidas --; //descontara la vida del jugador

if (vidas < 1)
    	exit("Se acaba la partida", 1); //he puesto un exit, puedes poner un proceso de titulo inicial
    else
    	nivel();
    end
    
    fade_on();
end

process nivel1();
begin    
	start_scroll(0, 0, 1, 2, 0, 0); //ponemos scroll de fondo
    ctype = c_scroll;
    scroll.camera = id;
      
    jugador(240, 200);
    enemigo1();
    enemigo1();
    
    write_int(0, 20, 20, 3, offset puntos);
    write(0, 240, 20, 4, "- Nivel 1 -");
    
    enemigos = 2;

loop
    	advance(1);
        angle += 1000;
    
		if (enemigos == 0)
        	pasar_nivel(nivel2); //funcion para pasar de nivel
       	end
    
        if (jugador_vive != 1)
           	reiniciar_nivel(nivel1);
        end
         
        frame;
    end
end

process nivel2();
begin
	start_scroll(0, 0, 5, 4, 0, 0); //ponemos scroll de fondo
    ctype = c_scroll;
    scroll.camera = id;

jugador(240, 200);
    enemigo1();
    enemigo2();
    enemigo2();

write_int(0, 20, 20, 3, offset puntos);
	write(0, 240, 20, 4, "- Nivel 2 -");

enemigos = 3;
      
	loop
       	advance(1);
        angle -= 1000;
    
        if (enemigos == 0)
        	pasar_nivel(nivel3); //funcion para pasar de nivel
        end

if (jugador_vive != 1)
    		reiniciar_nivel(nivel2);
    	end

frame;
	end
end

process nivel3();
begin

//aqui contruyes nivel 3
    exit("Has llegado al nivel 3", 1);
end

process jugador(x, y);
private
	disparado;
    
begin
	graph = 3;
	size  = 50;
	angle = 90000;
    
    jugador_vive = 1;
    
	loop
    	if (key(_left)) angle += 2000; end
		if (key(_right)) angle -= 2000; end
		
		if (key(_up)) advance(2); end
		if (key(_down)) advance(-1); end
		
		if (key(_space) and disparado < 1)
			disparo(x, y, angle);
			disparado = 5;
		end
				
		disparado --; if (disparado < 0) disparado = 0; end
        
    	frame;
    end
end

process disparo(x, y, angle);
begin
	graph = color_in_map(0, 3, cc_orange);
	size  = 15;
	z	  = 10;
	advance(20);
	
	loop
		advance(10);
		if (out_region(id, 0)) break; end
		
		frame;
	end
end

process enemigo1();
private
	id_disparo;
    
begin
	graph = 6;
    x	  = rand(20, 460);
    y	  = rand(20, 280);
    size  = rand(60, 120);
    
	loop
    	tone++;
        
    	id_disparo = collision(type disparo);
    	if (id_disparo)
        	enemigos --;
            puntos += 5;
            signal(id_disparo, s_kill);
            break;
        end
        
    	frame;
    end
end

process enemigo2();
private
	id_disparo;
    
begin
	graph = 7;
    x	  = rand(20, 460);
    y	  = rand(20, 280);
    size  = rand(60, 120);
    
	loop
    	tone++;
        
       	id_disparo = collision(type disparo);
    	if (id_disparo)
        	enemigos --;
            puntos += 10;
            signal(id_disparo, s_kill);
            break;
        end
        
    	frame;
    end
end

Tamaño Código:

HTML5 Game engine

Entorno de desarrollo de juegos online en HTML5