Div GO : Div Games Online

Haz clic para obtener el control del teclado

// by J. Manuel Habas

program ejemplo_juego3D;
global
	old_puntos, puntos;
    tex, txt;
    obj0, obj1, obj2, obj3, obj4, obj5;
    i;

private
    saltos = 23, move_x = -12, move_z = -352;

begin
    tex = load_fpg("graficos/texturas");
    txt = load_font("fuentes/LiquidCrystal-Normal.otf");
   
    set_mode(320, 200, 2);
    set_fps(60, 0);
    
    screen_smooth(false);
    screen_scanline(40, 2);
    
    start_scene3d(0, tex, 1, 0);
       
    for (i = 0; i < 14; i++)
    	obj2 = object3d(1, 0, cc_orange, 100, 2, -150 + (i * saltos), 12, -421);
		modify_object3d(obj2, 100, 22, 22, 22);
    end

for (i = 0; i < 15; i++)
    	obj2 = object3d(1, 0, cc_orange, 100, 2, -150, 12, -421 + (i * saltos));
		modify_object3d(obj2, 100, 22, 22, 22);
    end
    
    for (i = 0; i < 14; i++)
    	obj2 = object3d(1, 0, cc_orange, 100, 2, -150 + (i * saltos), 12, -76);
		modify_object3d(obj2, 100, 22, 22, 22);
    end
    
    for (i = 0; i < 15; i++)
    	obj2 = object3d(1, 0, cc_orange, 100, 2, 149, 12, -421 + (i * saltos));
		modify_object3d(obj2, 100, 22, 22, 22);
    end
    
    //fuente, wireframe, color, alpha, anchura, x, y, z, texto
    text_size = 200;
    obj0 = write_object3d(txt, 0, cc_white, 100, 22, -104, 12, 23, puntos);
    
    obj1 = object3d(1, 0, cc_green, 100, 2, move_x, 12, move_z);
	modify_object3d(obj1, 100, 22, 22, 22);

light3d(200, rgb(200, 160, 255), 10000, 0, 100, -200); //intensidad, color, distancia, x, y, z
    set_shadows(0, 50, 2); //aplica sombras
    set_fog(0, cc_black, 400, 1100);
    
    scene3d.light 	= 30;
    scene3d.camera 	= id;

ctype 	= c_scene3d;
	y		= 190;
    angle_y = -27000;
    
	loop
    	if (key(_up) and move_z < -99) move_z += saltos; end
        if (key(_down) and move_z > -398) move_z -= saltos; end
        if (key(_left) and move_x > -127) move_x -= saltos; end
        if (key(_right)  and move_x < 126) move_x += saltos; end

//id, x, y, z, angle_x, angle_y, angle_z
       	move_object3d(obj1, move_x, 12, move_z, 0, 0, 0);
       
       	if (rand(0, 100) == 0)
        	delete_object3d(obj3);
            
            obj3 = object3d(1, 0, cc_red, 100, 2, -127 + (rand(0, 11) * saltos), 12, -398 + (rand(0, 13) * saltos));
            modify_object3d(obj3, 100, 22, 22, 22);
        end
        
        if (rand(0, 200) == 0)
        	timer[0] = 0;
        	delete_object3d(obj4);
            
            obj4 = object3d(1, 0, cc_gray, 100, 2, -127 + (rand(0, 11) * saltos), 12, -398 + (rand(0, 13) * saltos));
            modify_object3d(obj4, 100, 22, 22, 22);
        end
        
        if (rand(0, 400) == 0)
        	timer[1] = 0;
        	delete_object3d(obj5);
            
            obj5 = object3d(1, 0, cc_yellow, 100, 2, -127 + (rand(0, 11) * saltos), 12, -398 + (rand(0, 13) * saltos));
            modify_object3d(obj5, 100, 22, 22, 22);
        end
        
        if (timer[0] == 200) delete_object3d(obj4); obj4 = 0; end
        if (timer[1] == 200) delete_object3d(obj5); obj5 = 0; end
        
        if (collision_objects3d(obj1, obj3))
            puntos += 25;
            
            delete_object3d(obj3);            
            obj3 = 0;
        end

if (collision_objects3d(obj1, obj4))
            puntos -= 50; if (puntos < 0) puntos = 0; end
            
            delete_object3d(obj4);            
            obj4 = 0;
        end

if (collision_objects3d(obj1, obj5))
            puntos += 250;
            
            delete_object3d(obj5);
            obj5 = 0;
        end
        
        if (puntos <> old_puntos)
        	old_puntos = puntos;
            
        	delete_object3d(obj0);
        	obj0 = write_object3d(txt, 0, cc_white, 100, 22, -104, 12, 23, puntos);
        end

frame;
    end
end

Tamaño Código:

HTML5 Game engine

Entorno de desarrollo de juegos online en HTML5