Div GO : Div Games Online

Haz clic para obtener el control del teclado

//--------------------------------------------------------------------
// Programa: Tutorial 2
// Autor:    Daniel Navarro Medrano
// Fecha:    20/10/97
//--------------------------------------------------------------------

PROGRAM Tutorial_2;
GLOBAL fichero[5];
BEGIN
    // Carga el archivo que contiene todos los gráficos
    fichero[0]=load_fpg("graficos/tutorial2");
    fichero[1]=change_fpg_color(fichero[0], cc_blue, cc_yellow, 100);
    fichero[2]=change_fpg_color(fichero[0], cc_blue, cc_white, 100);
    fichero[3]=change_fpg_color(fichero[0], cc_blue, cc_green, 100);
    fichero[4]=change_fpg_color(fichero[0], cc_blue, cc_orange, 100);

// Selecciona el tamaño de pantalla
	set_mode(m320x200,2);
    screen_smooth(false);
    
    // Selecciona el número de imagenes por segundo
    set_fps(24,0);
    // Pone la pantalla de fondo
    put_screen(fichero[0],41);
	// Selecciona el tamaño de la letra
	text_size = 50;
    // Escribe un texto explicativo
    write(0,160,2,1,"Pulse espacio para crear planetas");
    // Crea un bucle infinito, ya que como no hay ningun
    // proceso creado por ahora, el programa acabaria si no
    // hubiera dicho bucle
    LOOP
        // Cada vez que se pulsa la tecla espacio se crea un
        // proceso del tipo tierra
        IF (key(_space)) tierra(fichero[rand(0,4)]); END
        FRAME;
    END
END

//--------------------------------------------------------------------
// Proceso tierra
// Maneja las animaciones de la tierra
//--------------------------------------------------------------------

PROCESS tierra(file);

PRIVATE
    velocidad_x;         // Incremento en la coordenada horizontal
    velocidad_y;         // Incremento en la coordenada vertical
    velocidad_y_inicial; // Longitud del bote

BEGIN
    // Crea el proceso en la mitad del lateral izquierdo
    x=0; y=1800;
    resolution=10;  // Hace que las coordenadas usen un decimal
    // Inicia el incremento horizontal de 1 a 8 puntos
    velocidad_x=rand(10,80);
    // Reinicia la longitud del bote inicial entre 8 y 25 puntos
    velocidad_y_inicial=rand(-80,-250);
    // El incremento vertical es igual a la longitud del bote
    velocidad_y=velocidad_y_inicial;
    // Crea un bucle infinito
    LOOP
        // Crea un bucle que va pasando por todas las imagenes
        // que componen la animacion que va de los codigos 0 a 40
        FROM graph=1 TO 40;
            // Mueve el proceso horizontalmente
            x=x+velocidad_x;
            // Si llega a algun extremo de la pantalla
            IF (x<0 OR x>3200)
                // Cambia el signo del incremento y con ello
                // la dirección del movimiento
                velocidad_x=-velocidad_x;
            END
            // Mueve el proceso verticalmente
            y=y+velocidad_y;
            // Si la longitud del bote a llegado a su limite
            IF (-velocidad_y<=velocidad_y_inicial)
                // Reinicia la longitud a la inicial
                velocidad_y=-velocidad_y;
            ELSE
                // Va bajando el incremento en la longitud del bote
                velocidad_y=velocidad_y+20;
            END
            FRAME;  // Hace que el proceso aparezca en pantalla
        END
    END
END

Tamaño Código:

HTML5 Game engine

Entorno de desarrollo de juegos online en HTML5